ZPL - Zebra編程語言 - 打印頁面描述的語言，即所謂的PDL（頁面描述語言）。頁面描述語言有許多種。幾乎每個打印機制造商都有自己的頁面描述語言。這種語言允許您通過高級命令來描述頁面，這些命令將由打印機在低級命令中進行解釋。其中最著名的是Adobe的PostScript。PDL允許你描述頁面對象。有一些東西可以使程序獨立于打印機的特定硬件平臺。打印機接收打印正方形，符號或線條的命令，我們不關心它將如何實現(xiàn)。打印機本身知道如何做到這一點。這是PDL的主要優(yōu)點。

美國公司斑馬技術公司已開發(fā)ZPL，主要用于制作和打印標簽。標簽可以包含文本，條形碼和簡單的圖形。這些標簽印有特殊的斑馬打印機，這些打印機在貿易中用于打印收據(jù)和支票。

有兩個標準：ZPL和ZPL ll。

區(qū)別

ZPL II開發(fā)的主要原因是顯著減少了打印機開始接收數(shù)據(jù)和打印第一個字符之間的時間。這主要是通過改變ZPL程序的寫法來完成的。

ZPL II標準與ZPL標準不是100％兼容。但ZPL II和ZPL之間的差異很小。而且，ZPL上的現(xiàn)有程序可以很容易地修改為ZPL ll的級別。有向后兼容性。也就是說，您可以在ZPL ll上為ZPL打印機編寫程序，當然也可以使用舊的語法。

所以，這里是ZPL ll和ZPL的兩個主要區(qū)別：

1. 在ZPL II中，數(shù)據(jù)按收到的格式立即格式化。而在標準ZPL中，格式化不會開始，直到您獲得命令完成格式^ XZ。
2. ZPL ll有很多新的命令：^ JM，^ LH，^ LL，^ LR，^ LS，^ PM，^ PO，^ PR和^ PF

句法

但是，考慮一個沒有例子的編程語言是一個空洞的教訓。因此，我會給程序代碼打印一個簡單的標簽，我們將看看語法。

^XA
 
^FX Top section with company logo, name and address.
^CF0,60
^FO55,55^GC100^FS
^FO75,55^GC100^FS
^FO75,75^GC100^FS
^FO55,75^GC100^FS
^FO88,88^GC50,50^FS
^FO220,50^FDLorem Ipsum, Inc.^FS
^CF0,40
^FO220,100^FD1000 Shipping Lane^FS
^FO220,135^FDShelbyville TN 38102^FS
^FO220,170^FDEURO UNION (EU)^FS
^FO50,250^GB700,1,3^FS
 
^FX Second section with recipient address and permit information.
^CFA,30
^FO50,300^FDKarl Marks^FS
^FO50,340^FD100 Main Street^FS
^FO50,380^FDEURO UNION (EU)^FS
^CFA,15
^FO50,450^GB700,1,3^FS
 
^FX Third section with barcode.
^BY5,2,120
^FO175,500^BC^FD1234567890^FS
 
^FX Fourth section (the two boxes on the bottom).
^FO50,700^GB700,250,3^FS
^FO400,700^GB1,250,3^FS
^CF0,40
^FO100,760^FDShipping Ctr. Y74H-1^FS
^FO100,800^FDREF1 F99L17^FS
^FO100,840^FDREF2 YUH88^FS
^CF0,190
^FO485,765^FDAA^FS
 
^XZ

我們最終會收到一張控制交貨的票：

如您所見，代碼以標簽（命令）^ XA開始，以標簽^ XZ結束。為了方便考慮，代碼由評論劃分為四個部分。

1）第一部分顯示公司標志及其法律數(shù)據(jù)：

^FX Top section with company logo, name and address.
^CF0,60
^FO55,55^GC100^FS
^FO75,55^GC100^FS
^FO75,75^GC100^FS
^FO55,75^GC100^FS
^FO88,88^GC50,50^FS
^FO220,50^FDLorem Ipsum, Inc.^FS
^CF0,40
^FO220,100^FD1000 Shipping Lane^FS
^FO220,135^FDShelbyville TN 38102^FS
^FO220,170^FDEURO UNION (EU)^FS
^FO50,250^GB700,1,3^FS

很明顯，標簽^ FX意味著評論。

^CF x, y, z - 默認字體設置：字體，高度和寬度。

^FO x,y - 向左和向上縮進。

^FS - 行結束。

接下來，從四個圈畫一個標志：

^GC x,y - 畫一個圓圈。直徑是x，框架的厚度是y。

公司資料：

^FD是數(shù)據(jù)字段。

2）在新標簽的第二部分，我們沒有遇到。

3）在第三部分中，我們添加條形碼：

^FX Third section with barcode.
^BY5,2,120
^FO175,500^BC^FD1234567890^FS

在這里：

^BY x,y,z - 條的寬度，寬度，高度。

4）在第四部分中，出現(xiàn)了另一個標簽：

^GB x,y,z是一個矩形。框架的寬度，高度和厚度。

這里有一小組標簽，我們描述了整個印刷頁面。同意，沒什么復雜的。你只需要選擇以點為單位的距離。所有的測量都是以點為單位的。

當然，我們已經(jīng)考慮了ZPL命令中的一小部分，但現(xiàn)在你對這種語言有了一些了解。

在互聯(lián)網(wǎng)上有許多ZPL代碼的在線口譯員。所以你可以隨時測試它。

我們在FastReport中添加了以ZPL格式打印報表的功能，請免費下載試用。

產(chǎn)品介紹 | 下載試用 | 優(yōu)惠活動 | | 聯(lián)系Elyn